FM / api

/usr/src/linux-headers-5.15.0-181/scripts/coccinelle/api/

/usr/src/linux-headers-5.15.0-181/scripts/coccinelle/api

Name	Size	Mode	Actions
alloc/	-	0755	rm
debugfs/	-	0755	rm
atomic_as_refcounter.cocci	2272	0644	edit dl rm
check_bq27xxx_data.cocci	3538	0644	edit dl rm
device_attr_show.cocci	1104	0644	edit dl rm
d_find_alias.cocci	1309	0644	edit dl rm
err_cast.cocci	1114	0644	edit dl rm
kfree_mismatch.cocci	5691	0644	edit dl rm
kfree_sensitive.cocci	1951	0644	edit dl rm
kstrdup.cocci	2478	0644	edit dl rm
kvmalloc.cocci	6287	0644	edit dl rm
memdup.cocci	1367	0644	edit dl rm
memdup_user.cocci	2645	0644	edit dl rm
platform_get_irq.cocci	1248	0644	edit dl rm
platform_no_drv_owner.cocci	3902	0644	edit dl rm
pm_runtime.cocci	2428	0644	edit dl rm
resource_size.cocci	2132	0644	edit dl rm
simple_open.cocci	1244	0644	edit dl rm
stream_open.cocci	7880	0644	edit dl rm
vma_pages.cocci	1519	0644	edit dl rm

Edit: /usr/src/linux-headers-5.15.0-181/scripts/coccinelle/api/platform_get_irq.cocci (1248B)

// SPDX-License-Identifier: GPL-2.0
/// Remove dev_err() messages after platform_get_irq*() failures
//
// Confidence: Medium
// Options: --include-headers

virtual patch
virtual context
virtual org
virtual report

@depends on context@
expression ret;
struct platform_device *E;
@@

ret =
(
platform_get_irq
|
platform_get_irq_byname
)(E, ...);

if ( \( ret < 0 \| ret <= 0 \) )
{
(
if (ret != -EPROBE_DEFER)
{ ...
*dev_err(...);
... }
|
...
*dev_err(...);
)
...
}

@depends on patch@
expression ret;
struct platform_device *E;
@@

ret =
(
platform_get_irq
|
platform_get_irq_byname
)(E, ...);

if ( \( ret < 0 \| ret <= 0 \) )
{
(
-if (ret != -EPROBE_DEFER)
-{ ...
-dev_err(...);
-... }
|
...
-dev_err(...);
)
...
}

@r depends on org || report@
position p1;
expression ret;
struct platform_device *E;
@@

ret =
(
platform_get_irq
|
platform_get_irq_byname
)(E, ...);

if ( \( ret < 0 \| ret <= 0 \) )
{
(
if (ret != -EPROBE_DEFER)
{ ...
dev_err@p1(...);
... }
|
...
dev_err@p1(...);
)
...
}

@script:python depends on org@
p1 << r.p1;
@@

cocci.print_main(p1)

@script:python depends on report@
p1 << r.p1;
@@

msg = "line %s is redundant because platform_get_irq() already prints an error" % (p1[0].line)
coccilib.report.print_report(p1[0],msg)

cmd: